Algoritmo calificaciones

/// --- definiciones ---

Definir i, numero\_estudiantes, variable\_menu Como Entero

Definir contador, promedio\_general, mejor, peor Como Real

Definir salida Como Logico

salida <- Falso

/// --- ingreso de datos ---

Escribir "¿Cuántos alumnos tenés en el curso?"

Leer numero\_estudiantes

Dimensionar nombre[numero\_estudiantes]

Dimensionar apellido[numero\_estudiantes]

Dimensionar nota1[numero\_estudiantes]

Dimensionar nota2[numero\_estudiantes]

Dimensionar promedio[numero\_estudiantes]

/// --- cargar datos y calcular promedios ---

Para i <- 1 Hasta numero\_estudiantes Hacer

Escribir "Nombre del estudiante:"

Leer nombre[i]

Escribir "Apellido del estudiante:"

Leer apellido[i]

Escribir "Nota del 1er cuatrimestre:"

Leer nota1[i]

Escribir "Nota del 2do cuatrimestre:"

Leer nota2[i]

promedio[i] <- (nota1[i] + nota2[i]) / 2

Fin Para

/// --- mostrar resumen inicial ---

Para i <- 1 Hasta numero\_estudiantes Hacer

Escribir "Nombre: ", nombre[i], " ", apellido[i], " | 1er: ", nota1[i], " | 2do: ", nota2[i], " | Promedio: ", promedio[i]

Escribir ""

Fin Para

/// --- menú de opciones ---

Repetir

Escribir ""

Escribir "<-!----------------------------!->"

Escribir "¿Qué querés calcular?"

Escribir "1 - Total de aprobados"

Escribir "2 - Total de desaprobados"

Escribir "3 - Promedio general del curso"

Escribir "4 - Mejor promedio"

Escribir "5 - Peor promedio"

Escribir "6 - Salir"

Escribir "<-!----------------------------!->"

Leer variable\_menu

Segun variable\_menu Hacer

1:

contador <- 0

Para i <- 1 Hasta numero\_estudiantes Hacer

Si promedio[i] >= 6 Entonces

contador <- contador + 1

FinSi

Fin Para

Escribir "Total de aprobados: ", contador

2:

contador <- 0

Para i <- 1 Hasta numero\_estudiantes Hacer

Si promedio[i] < 6 Entonces

contador <- contador + 1

FinSi

Fin Para

Escribir "Total de desaprobados: ", contador

3:

contador <- 0

Para i <- 1 Hasta numero\_estudiantes Hacer

contador <- contador + promedio[i]

Fin Para

promedio\_general <- contador / numero\_estudiantes

Escribir "Promedio general del curso: ", promedio\_general

4:

mejor <- promedio[1]

Para i <- 2 Hasta numero\_estudiantes Hacer

Si promedio[i] > mejor Entonces

mejor <- promedio[i]

FinSi

Fin Para

Escribir "Mejor promedio: ", mejor

5:

peor <- promedio[1]

Para i <- 2 Hasta numero\_estudiantes Hacer

Si promedio[i] < peor Entonces

peor <- promedio[i]

FinSi

Fin Para

Escribir "Peor promedio: ", peor

6:

salida <- Verdadero

Escribir "Saliendo del programa..."

De Otro Modo:

Escribir "Elegí una opción válida."

Fin Segun

Hasta Que salida = Verdadero

FinAlgoritmo